1 |
|
|
module Microlayer_m |
2 |
|
|
|
3 |
|
|
Implicit none |
4 |
|
|
|
5 |
|
|
contains |
6 |
|
|
|
7 |
|
|
subroutine Microlayer(dter, dser, tkt, tks, hlb, tau, s_subskin, al, & |
8 |
|
|
xlv, taur, rf, rain, qcol) |
9 |
|
|
|
10 |
|
|
! H. Bellenger 2016 |
11 |
|
|
|
12 |
|
|
use const, only: beta, cpw, grav, rhow |
13 |
|
|
use fv_m, only: fv |
14 |
|
|
|
15 |
|
|
real, intent(out):: dter(:) |
16 |
|
|
! Temperature variation in the diffusive microlayer, that is |
17 |
|
|
! ocean-air interface temperature minus subskin temperature. In K. |
18 |
|
|
|
19 |
|
|
real, intent(out):: dser(:) |
20 |
|
|
! Salinity variation in the diffusive microlayer, that is ocean-air |
21 |
|
|
! interface salinity minus subskin salinity. In ppt. |
22 |
|
|
|
23 |
|
|
real, intent(inout):: tkt(:) |
24 |
|
|
! thickness of cool skin (microlayer), in m |
25 |
|
|
|
26 |
|
|
real, intent(inout):: tks(:) |
27 |
|
|
! thickness of mass diffusion layer (microlayer), in m |
28 |
|
|
|
29 |
|
|
real, intent(in):: hlb(:) |
30 |
|
|
! latent heat flux at the surface, positive upward (W m-2) |
31 |
|
|
|
32 |
|
|
real, intent(in):: tau(:) ! wind stress, turbulent part only, in Pa |
33 |
|
|
real, intent(in):: s_subskin(:) ! subskin salinity, in ppt |
34 |
|
|
real, intent(in):: al(:) ! water thermal expansion coefficient (in K-1) |
35 |
|
|
real, intent(in):: xlv(:) ! latent heat of evaporation (J/kg) |
36 |
|
|
real, intent(in):: taur(:) ! momentum flux due to rainfall, in Pa |
37 |
|
|
|
38 |
|
|
real, intent(in):: rf(:) |
39 |
|
|
! sensible heat flux at the surface due to rainfall, in W m-2 |
40 |
|
|
|
41 |
|
|
real, intent(in):: rain(:) ! rain mass flux, in kg m-2 s-1 |
42 |
|
|
|
43 |
|
|
real, intent(in):: qcol(:) |
44 |
|
|
! net flux at the surface, without sensible heat flux due to rain, in W m-2 |
45 |
|
|
|
46 |
|
|
! Local: |
47 |
|
|
|
48 |
|
|
real, dimension(size(qcol)):: usrk, usrct, usrcs, alq |
49 |
|
|
real xlamx(size(qcol)) ! Saunders coefficient |
50 |
|
|
real, parameter:: visw = 1e-6 |
51 |
|
|
real, parameter:: tcw = 0.6 ! thermal conductivity of water |
52 |
|
|
|
53 |
|
|
real, parameter:: mu = 0.0129e-7 ! in m2 / s |
54 |
|
|
! molecular salinity diffusivity, Kraus and Businger, page 47 |
55 |
|
|
|
56 |
|
|
real, parameter:: kappa = 1.49e-7 ! thermal diffusivity, in m2 / s |
57 |
|
|
|
58 |
|
|
real, parameter:: afk = 4e-4 |
59 |
|
|
real, parameter:: bfk = 1.3 |
60 |
|
|
! a and b coefficient for the power function fitting the TKE flux |
61 |
|
|
! carried by rain: Fk = a * R**b, derived form the exact solution |
62 |
|
|
! of Soloviev and Lukas 2006 (Schlussel et al 1997, Craeye and |
63 |
|
|
! Schlussel 1998) |
64 |
|
|
|
65 |
|
|
!-------------------------------------------------------------------------- |
66 |
|
|
|
67 |
|
|
alq = al * (qcol + rf * (1 - fV(tkt, rain))) - beta * s_subskin * cpw & |
68 |
|
|
* (hlb / xlv - rain * (1 - fV(tks, rain))) |
69 |
|
|
|
70 |
|
|
usrk = (afk / rhow)**(1. / 3.) * (rain * 3600.)**(bfk / 3.) |
71 |
|
|
! Equivalent friction velocity due to the TKE input by the penetrating |
72 |
|
|
! raindrops Fk |
73 |
|
|
|
74 |
|
|
! Friction velocities in the air: |
75 |
|
|
usrct = sqrt((tau + (1. - fV(tkt, rain)) * taur) / rhow & |
76 |
|
|
+ (fV(0., rain) - fV(tkt, rain)) * usrk**2) |
77 |
|
|
usrcs = sqrt((tau + (1. - fV(tks, rain)) * taur) / rhow & |
78 |
|
|
+ (fV(0., rain) - fV(tks, rain)) * usrk**2) |
79 |
|
|
|
80 |
|
|
where (alq > 0.) |
81 |
|
|
! Fairall 1996 982, equation (14): |
82 |
|
|
xlamx = 6. * (1. + (16. * grav * cpw * rhow * visw**3 * alq & |
83 |
|
|
/ (tcw**2 * usrct**4 ))**0.75)**(- 1. / 3.) |
84 |
|
|
|
85 |
|
|
! Fairall 1996 982, equation (12): |
86 |
|
|
tkt = xlamx * visw / usrct |
87 |
|
|
|
88 |
|
|
tks = xlamx * mu * (kappa / mu)**(2. / 3.) & |
89 |
|
|
* visw * cpw * rhow / ( tcw * usrcs) |
90 |
|
|
! From Saunders 1967 (4) |
91 |
|
|
elsewhere |
92 |
|
|
xlamx = 6. ! prevent excessive warm skins |
93 |
|
|
tkt = min(.01, xlamx * visw / usrct) ! Limit tkt |
94 |
|
|
tks = min(.001, xlamx * mu * (kappa / mu)**(2. / 3.) * visw * cpw & |
95 |
|
|
* rhow / (tcw * usrcs)) |
96 |
|
|
end where |
97 |
|
|
|
98 |
|
|
! Fairall 1996 982, equation (13): |
99 |
|
|
dter = - (qcol + rf * (1 - fV(tkt, rain))) * tkt / tcw |
100 |
|
|
|
101 |
|
|
dser = s_subskin * (hlb / xlv - rain * (1 - fV(tks, rain))) * tks & |
102 |
|
|
/ (rhow * mu) ! eq. fresh skin |
103 |
|
|
|
104 |
|
|
end subroutine Microlayer |
105 |
|
|
|
106 |
|
|
end module Microlayer_m |