lw.F90

Go to the documentation of this file.

SUBROUTINE lw &
 &( kidia, kfdia , klon  , klev  , kmode &
 &, pcco2, pcldld, pcldlu &
 &, pdp  , pdt0  , pemis , pemiw &
 &, ppmb , pqof  , ptl &
 &, paer , ptave , pview , pwv &
 &, pcolr, pcolc , pemit , pflux , pfluc &
 &)

!**** *LW*   - ORGANIZES THE LONGWAVE CALCULATIONS

!     PURPOSE.
!     --------
!           COMPUTES LONGWAVE FLUXES 

!**   INTERFACE.
!     ----------

!        *LW* IS CALLED FROM *RADLSW*

!        EXPLICIT ARGUMENTS :
!        --------------------
! PAER   : (KLON,6,KLEV)     ; OPTICAL THICKNESS OF THE AEROSOLS
! PCCO2  :                   ; CONCENTRATION IN CO2 (PA/PA)
! PCLDLD : (KLON,KLEV)       ; DOWNWARD EFFECTIVE CLOUD FRACTION
! PCLDLU : (KLON,KLEV)       ; UPWARD EFFECTIVE CLOUD FRACTION
! PDP    : (KLON,KLEV)       ; LAYER PRESSURE THICKNESS
! PDT0   : (KLON)            ; SURFACE TEMPERATURE DISCONTINUITY  
! PEMIS  : (KLON)            ; SURFACE LW EMISSIVITY
! PEMIW  : (KLON)            ; SURFACE LW WINDOW EMISSIVITY
! PPMB   : (KLON,KLEV+1)     ; HALF LEVEL PRESSURE
! PQOF   : (KLON,KLEV)       ; CONCENTRATION IN OZONE (PA/PA)
! PTAVE  : (KLON,KLEV)       ; TEMPERATURE
! PTL    : (KLON,KLEV+1)     ; HALF LEVEL TEMPERATURE
! PVIEW  : (KLON)            ; COSECANT OF VIEWING ANGLE
! PWV    : (KLON,KLEV)       ; SPECIFIC HUMIDITY  (PA/PA)
!     ==== OUTPUTS ===
! PCOLR(KLON,KLEV)           ; LONG-WAVE TENDENCY
! PCOLC(KLON,KLEV)           ; LONG-WAVE TENDENCY CLEAR SKY
! PEMIT(KLON)                ; SURFACE TOTAL LW EMISSIVITY
! PFLUX(KLON,2,KLEV)         ; RADIATIVE FLUXES :
!                     1  ==>  UPWARD   FLUX TOTAL
!                     2  ==>  DOWNWARD FLUX TOTAL
! PFLUC(KLON,2,KLEV)         ; RADIATIVE FLUXES CLEAR SKY:
!                     1  ==>  UPWARD   FLUX TOTAL
!                     2  ==>  DOWNWARD FLUX TOTAL

!        IMPLICIT ARGUMENTS :   NONE
!        --------------------

!     METHOD.
!     -------

!          1. COMPUTES THE PRESSURE AND TEMPERATURE WEIGHTED AMOUNTS OF
!     ABSORBERS.
!          2. COMPUTES THE PLANCK FUNCTIONS ON THE INTERFACES AND THE
!     GRADIENT OF PLANCK FUNCTIONS IN THE LAYERS.
!          3. PERFORMS THE VERTICAL INTEGRATION DISTINGUISHING THE CON-
!     TRIBUTIONS OF THE ADJACENT AND DISTANT LAYERS AND THOSE FROM THE
!     BOUNDARIES.
!          4. COMPUTES THE CLEAR-SKY DOWNWARD AND UPWARD EMISSIVITIES.
!          5. INTRODUCES THE EFFECTS OF THE CLOUDS ON THE FLUXES.

!     EXTERNALS.
!     ----------

!          *LWU*, *LWBV*, *LWC*

!     REFERENCE.
!     ----------

!        SEE RADIATION'S PART OF THE MODEL'S DOCUMENTATION AND
!        ECMWF RESEARCH DEPARTMENT DOCUMENTATION OF THE IFS

!     AUTHOR.
!     -------
!        JEAN-JACQUES MORCRETTE  *ECMWF*

!     MODIFICATIONS.
!     --------------
!        ORIGINAL : 89-07-14
!        99-05-25   JJMorcrette    Revised aerosols

!-----------------------------------------------------------------------

#include "tsmbkind.h"

USE yoelw    , ONLY : nua
USE yoerdu   , ONLY : rcday


IMPLICIT NONE


!     DUMMY INTEGER SCALARS
integer_m :: kfdia
integer_m :: kidia
integer_m :: klev
integer_m :: klon
integer_m :: kmode

!     DUMMY REAL SCALARS
real_b :: pcco2



!-----------------------------------------------------------------------

!*       0.1   ARGUMENTS
!              ---------

real_b :: paer(klon,6,klev)&
  &,  pcldld(klon,klev)   , pcldlu(klon,klev)&
  &,  pdp(klon,klev)      , pdt0(klon)       &
  &,  pemis(klon)         , pemiw(klon)&
  &,  ppmb(klon,klev+1)&
  &,  pqof(klon,klev)  &
  &,  ptl(klon,klev+1)    , ptave(klon,klev) &
  &,  pview(klon)         , pwv(klon,klev)

real_b :: pcolr(klon,klev)    , pcolc(klon,klev)&
  &,  pemit(klon) &
  &,  pflux(klon,2,klev+1), pfluc(klon,2,klev+1)

!-------------------------------------------------------------------------

!*       0.2   LOCAL ARRAYS
!              ------------
real_b :: zabcu(klon,nua,3*klev+1)&
  &,  zbint(klon,klev+1)        , zbsui(klon)&
  &,  zcntrb(klon,klev+1,klev+1)

!     LOCAL INTEGER SCALARS
integer_m :: jk, jkl, jl

!     LOCAL REAL SCALARS
real_b :: zdcnet, zdfnet


!     ------------------------------------------------------------------

!*         1.    INITIALIZATION
!                --------------

!100  CONTINUE

!     ------------------------------------------------------------------

!*         1.1   COMPUTES ABSORBER AMOUNTS
!                -------------------------

CALL lwu &
  &(  kidia, kfdia, klon, klev &
  &,  paer , pcco2, pdp , ppmb, pqof , ptave, pview, pwv &
  &,  zabcu &
  &)

!     ------------------------------------------------------------------

!*         2.    COMPUTES PLANCK FUNCTIONS
!                -------------------------
!                PERFORMS THE VERTICAL INTEGRATION
!                ---------------------------------

CALL lwbv &
   &( kidia, kfdia, klon , klev  , kmode &
   &, pdt0 , pemis, pemiw, ptl   , ptave &
   &, pemit, pfluc &
   &, zabcu, zbint, zbsui, zcntrb &
   &)

!     ------------------------------------------------------------------

!*         4.    INTRODUCES THE EFFECTS OF CLOUDS
!                --------------------------------

!print *,'Just before LWC'
CALL lwc &
  &( kidia , kfdia, klon  , klev &
  &, zbint , zbsui, pcldld, pcldlu &
  &, zcntrb, pemit, pfluc &
  &, pflux    &
  &)

DO jkl = 1 , klev
  jk = klev+1 - jkl
  DO jl = kidia,kfdia
    zdcnet = pfluc(jl,1,jk+1) + pfluc(jl,2,jk+1)&
     &-pfluc(jl,1,jk  ) - pfluc(jl,2,jk  )
    pcolc(jl,jk) = rcday * zdcnet / pdp(jl,jkl)
    zdfnet = pflux(jl,1,jk+1) + pflux(jl,2,jk+1)&
     &-pflux(jl,1,jk  ) - pflux(jl,2,jk  )
    pcolr(jl,jk) = rcday * zdfnet / pdp(jl,jkl)
  ENDDO
ENDDO

!     ------------------------------------------------------------------

RETURN
END SUBROUTINE lw