rrtm_cmbgb5.F90

Go to the documentation of this file.

!***************************************************************************
SUBROUTINE rrtm_cmbgb5
!***************************************************************************

!     BAND 5:  700-820 cm-1 (low - H2O,CO2; high - O3,CO2)
!***************************************************************************

! Parameters
#include "tsmbkind.h"

USE parrrtm  , ONLY : jpband   ,jpg      ,jpxsec   ,jpgpt 

USE yoerrto5 , ONLY : kao     ,kbo     ,selfrefo   ,fracrefao  ,&
           &fracrefbo, ccl4o
USE yoerrta5 , ONLY : ka      ,kb      ,selfref    ,fracrefa   ,&
             &        fracrefb,ccl4                            ,&
             &        absa    ,absb    ,ng5
USE yoerrtrwt, ONLY : frefa    ,frefb    ,frefadf  ,frefbdf   ,rwgt
USE yoerrtftr, ONLY : ngc      ,ngs      ,ngn      ,ngb       ,ngm     , wt

IMPLICIT NONE

!     LOCAL INTEGER SCALARS
integer_m :: igc, ipr, iprsm, jn, jp, jt
integer_m :: meq, neq                    ! To force equivalence, HG, 13-DEC-2003

!     LOCAL REAL SCALARS
real_b :: sumf, sumk


DO jn = 1,9
  DO jt = 1,5
    DO jp = 1,13
      iprsm = 0
      DO igc = 1,ngc(5)
        sumk = _zero_
        DO ipr = 1, ngn(ngs(4)+igc)
          iprsm = iprsm + 1

          sumk = sumk + kao(jn,jt,jp,iprsm)*rwgt(iprsm+64)
        ENDDO

        ka(jn,jt,jp,igc) = sumk
      ENDDO
    ENDDO
  ENDDO
ENDDO
DO jn = 1,5
  DO jt = 1,5
    DO jp = 13,59
      iprsm = 0
      DO igc = 1,ngc(5)
        sumk = _zero_
        DO ipr = 1, ngn(ngs(4)+igc)
          iprsm = iprsm + 1

          sumk = sumk + kbo(jn,jt,jp,iprsm)*rwgt(iprsm+64)
        ENDDO

        kb(jn,jt,jp,igc) = sumk
      ENDDO
    ENDDO
  ENDDO
ENDDO

DO jt = 1,10
  iprsm = 0
  DO igc = 1,ngc(5)
    sumk = _zero_
    DO ipr = 1, ngn(ngs(4)+igc)
      iprsm = iprsm + 1

      sumk = sumk + selfrefo(jt,iprsm)*rwgt(iprsm+64)
    ENDDO

    selfref(jt,igc) = sumk
  ENDDO
ENDDO

DO jp = 1,9
  iprsm = 0
  DO igc = 1,ngc(5)
    sumf = _zero_
    DO ipr = 1, ngn(ngs(4)+igc)
      iprsm = iprsm + 1

      sumf = sumf + fracrefao(iprsm,jp)
    ENDDO

    fracrefa(igc,jp) = sumf
  ENDDO
ENDDO

DO jp = 1,5
  iprsm = 0
  DO igc = 1,ngc(5)
    sumf = _zero_
    DO ipr = 1, ngn(ngs(4)+igc)
      iprsm = iprsm + 1

      sumf = sumf + fracrefbo(iprsm,jp)
    ENDDO

    fracrefb(igc,jp) = sumf
  ENDDO
ENDDO

iprsm = 0
DO igc = 1,ngc(5)
  sumk = _zero_
  DO ipr = 1, ngn(ngs(4)+igc)
    iprsm = iprsm + 1

    sumk = sumk + ccl4o(iprsm)*rwgt(iprsm+64)
  ENDDO

  ccl4(igc) = sumk
ENDDO

DO jp = 1,9
  DO igc = 1,ngc(5)

    frefa(ngs(4)+igc,jp) = fracrefa(igc,jp)
  ENDDO
ENDDO
DO jp = 1,8
  DO igc = 1,ngc(5)


    frefadf(ngs(4)+igc,jp) = fracrefa(igc,jp+1) -fracrefa(igc,jp)
  ENDDO
ENDDO
DO jp = 1,5
  DO igc = 1,ngc(5)

    frefb(ngs(4)+igc,jp) = fracrefb(igc,jp)
  ENDDO
ENDDO
DO jp = 1,4
  DO igc = 1,ngc(5)


    frefbdf(ngs(4)+igc,jp) = fracrefb(igc,jp+1) -fracrefb(igc,jp)
  ENDDO
ENDDO


! +--Force the equivalence: BEGIN (HG, 13-DEC-2003)
! +  ============================

! +--ABSA
! +  ^^^^
         jn  = 0
         jt  = 1
         jp  = 1
         igc = 1
      DO neq=1,ng5
      DO meq=1,585
             jn =  jn  + 1
      IF   ( jn == 9   + 1)                                         THEN
             jn =  1
             jt =  jt  + 1
       IF  ( jt == 5   + 1 )                                        THEN
             jt =  1
             jp =  jp  + 1
        IF ( jp == 13  + 1 )                                        THEN
             jp =  1
             igc=  igc + 1
        END IF
       END IF
      END IF
             absa(meq,neq) = ka(jn,jt,jp,igc)
      ENDDO
      ENDDO

! +--ABSB
! +  ^^^^
         jn  = 0
         jt  = 1
         jp  = 13
         igc = 1
      DO neq=1,ng5
      DO meq=1,1175
             jn =  jn  + 1
      IF   ( jn == 5   + 1)                                         THEN
             jn =  1
             jt =  jt  + 1
       IF  ( jt == 5   + 1 )                                        THEN
             jt =  1
             jp =  jp  + 1
        IF ( jp == 59  + 1 )                                        THEN
             jp =  13
             igc=  igc + 1
        END IF
       END IF
      END IF
             absb(meq,neq) = kb(jn,jt,jp,igc)
      ENDDO
      ENDDO

! +--Force the equivalence: END   (HG, 13-DEC-2003)
! +  ==========================


RETURN
END SUBROUTINE rrtm_cmbgb5