rrtm_cmbgb10.F90

Go to the documentation of this file.

!***************************************************************************
SUBROUTINE rrtm_cmbgb10
!***************************************************************************

!     BAND 10:  1390-1480 cm-1 (low - H2O; high - H2O)
!***************************************************************************

! Parameters
USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook

USE yoerrto10, ONLY : kao     ,kbo      ,fracrefao   ,fracrefbo
USE yoerrta10, ONLY : ka      ,kb       ,fracrefa    ,fracrefb
USE yoerrtrwt, ONLY : frefa    ,frefb    ,rwgt
USE yoerrtftr, ONLY : ngc      ,ngs      ,ngn      

IMPLICIT NONE

INTEGER(KIND=JPIM) :: IGC, IPR, IPRSM, JP, JT

REAL(KIND=JPRB) :: Z_SUMF1, Z_SUMF2, Z_SUMK
REAL(KIND=JPRB) :: ZHOOK_HANDLE

IF (lhook) CALL dr_hook('RRTM_CMBGB10',0,zhook_handle)
DO jt = 1,5
  DO jp = 1,13
    iprsm = 0
    DO igc = 1,ngc(10)
      z_sumk = 0.0_jprb
      DO ipr = 1, ngn(ngs(9)+igc)
        iprsm = iprsm + 1

        z_sumk = z_sumk + kao(jt,jp,iprsm)*rwgt(iprsm+144)
      ENDDO

      ka(jt,jp,igc) = z_sumk
    ENDDO
  ENDDO
ENDDO
DO jt = 1,5
  DO jp = 13,59
    iprsm = 0
    DO igc = 1,ngc(10)
      z_sumk = 0.0_jprb
      DO ipr = 1, ngn(ngs(9)+igc)
        iprsm = iprsm + 1

        z_sumk = z_sumk + kbo(jt,jp,iprsm)*rwgt(iprsm+144)
      ENDDO

      kb(jt,jp,igc) = z_sumk
    ENDDO
  ENDDO
ENDDO

iprsm = 0
DO igc = 1,ngc(10)
  z_sumf1= 0.0_jprb
  z_sumf2= 0.0_jprb
  DO ipr = 1, ngn(ngs(9)+igc)
    iprsm = iprsm + 1

    z_sumf1= z_sumf1+ fracrefao(iprsm)
    z_sumf2= z_sumf2+ fracrefbo(iprsm)
  ENDDO

  fracrefa(igc) = z_sumf1
  fracrefb(igc) = z_sumf2
ENDDO

DO igc = 1,ngc(10)

  frefa(ngs(9)+igc,1) = fracrefa(igc)
  frefb(ngs(9)+igc,1) = fracrefb(igc)
ENDDO

IF (lhook) CALL dr_hook('RRTM_CMBGB10',1,zhook_handle)
END SUBROUTINE rrtm_cmbgb10