rrtm_cmbgb16.F90

Go to the documentation of this file.

!***************************************************************************
SUBROUTINE rrtm_cmbgb16
!***************************************************************************

!     BAND 16:  2600-3000 cm-1 (low - H2O,CH4; high - nothing)
!***************************************************************************

! Parameters
USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook

USE yoerrto16, ONLY : kao     ,selfrefo   ,fracrefao
USE yoerrta16, ONLY : ka      ,selfref    ,fracrefa
USE yoerrtrwt, ONLY : frefa    ,frefadf  ,rwgt
USE yoerrtftr, ONLY : ngc      ,ngs      ,ngn      

IMPLICIT NONE

INTEGER(KIND=JPIM) :: IGC, IPR, IPRSM, JN, JP, JT

REAL(KIND=JPRB) :: Z_SUMF, Z_SUMK
REAL(KIND=JPRB) :: ZHOOK_HANDLE

IF (lhook) CALL dr_hook('RRTM_CMBGB16',0,zhook_handle)
DO jn = 1,9
  DO jt = 1,5
    DO jp = 1,13
      iprsm = 0
      DO igc = 1,ngc(16)
        z_sumk = 0.0_jprb
        DO ipr = 1, ngn(ngs(15)+igc)
          iprsm = iprsm + 1

          z_sumk = z_sumk + kao(jn,jt,jp,iprsm)*rwgt(iprsm+240)
        ENDDO

        ka(jn,jt,jp,igc) = z_sumk
      ENDDO
    ENDDO
  ENDDO
ENDDO

DO jt = 1,10
  iprsm = 0
  DO igc = 1,ngc(16)
    z_sumk = 0.0_jprb
    DO ipr = 1, ngn(ngs(15)+igc)
      iprsm = iprsm + 1

      z_sumk = z_sumk + selfrefo(jt,iprsm)*rwgt(iprsm+240)
    ENDDO

    selfref(jt,igc) = z_sumk
  ENDDO
ENDDO

DO jp = 1,9
  iprsm = 0
  DO igc = 1,ngc(16)
    z_sumf = 0.0_jprb
    DO ipr = 1, ngn(ngs(15)+igc)
      iprsm = iprsm + 1

      z_sumf = z_sumf + fracrefao(iprsm,jp)
    ENDDO

    fracrefa(igc,jp) = z_sumf
  ENDDO
ENDDO

DO jp = 1,9
  DO igc = 1,ngc(16)

    frefa(ngs(15)+igc,jp) = fracrefa(igc,jp)
  ENDDO
ENDDO

DO jp = 1,8
  DO igc = 1,ngc(16)

    frefadf(ngs(15)+igc,jp) = fracrefa(igc,jp+1) -fracrefa(igc,jp)
  ENDDO
ENDDO

IF (lhook) CALL dr_hook('RRTM_CMBGB16',1,zhook_handle)
END SUBROUTINE rrtm_cmbgb16