rrtm_cmbgb6.F90

Go to the documentation of this file.

!***************************************************************************
SUBROUTINE rrtm_cmbgb6
!***************************************************************************

!     BAND 6:  820-980 cm-1 (low - H2O; high - nothing)
!***************************************************************************

! Parameters
USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook

USE yoerrto6 , ONLY : kao     ,selfrefo   ,fracrefao  ,&
 & absco2o ,cfc11adjo,cfc12o  
USE yoerrta6 , ONLY : ka      ,selfref    ,fracrefa   ,&
 & absco2  ,cfc11adj ,cfc12  
USE yoerrtrwt, ONLY : frefa    ,frefb    ,rwgt
USE yoerrtftr, ONLY : ngc      ,ngs      ,ngn      

IMPLICIT NONE

INTEGER(KIND=JPIM) :: IGC, IPR, IPRSM, JP, JT

REAL(KIND=JPRB) :: Z_SUMF, Z_SUMK, Z_SUMK1, Z_SUMK2, Z_SUMK3
REAL(KIND=JPRB) :: ZHOOK_HANDLE

IF (lhook) CALL dr_hook('RRTM_CMBGB6',0,zhook_handle)
DO jt = 1,5
  DO jp = 1,13
    iprsm = 0
    DO igc = 1,ngc(6)
      z_sumk = 0.0_jprb
      DO ipr = 1, ngn(ngs(5)+igc)
        iprsm = iprsm + 1

        z_sumk = z_sumk + kao(jt,jp,iprsm)*rwgt(iprsm+80)
      ENDDO

      ka(jt,jp,igc) = z_sumk
    ENDDO
  ENDDO
ENDDO

DO jt = 1,10
  iprsm = 0
  DO igc = 1,ngc(6)
    z_sumk = 0.0_jprb
    DO ipr = 1, ngn(ngs(5)+igc)
      iprsm = iprsm + 1

      z_sumk = z_sumk + selfrefo(jt,iprsm)*rwgt(iprsm+80)
    ENDDO

    selfref(jt,igc) = z_sumk
  ENDDO
ENDDO

iprsm = 0
DO igc = 1,ngc(6)
  z_sumf = 0.0_jprb
  z_sumk1= 0.0_jprb
  z_sumk2= 0.0_jprb
  z_sumk3= 0.0_jprb
  DO ipr = 1, ngn(ngs(5)+igc)
    iprsm = iprsm + 1

    z_sumf = z_sumf + fracrefao(iprsm)
    z_sumk1= z_sumk1+ absco2o(iprsm)*rwgt(iprsm+80)
    z_sumk2= z_sumk2+ cfc11adjo(iprsm)*rwgt(iprsm+80)
    z_sumk3= z_sumk3+ cfc12o(iprsm)*rwgt(iprsm+80)
  ENDDO

  fracrefa(igc) = z_sumf
  absco2(igc) = z_sumk1
  cfc11adj(igc) = z_sumk2
  cfc12(igc) = z_sumk3
ENDDO

DO igc = 1,ngc(6)

  frefa(ngs(5)+igc,1) = fracrefa(igc)
  frefb(ngs(5)+igc,1) = fracrefa(igc)
ENDDO

IF (lhook) CALL dr_hook('RRTM_CMBGB6',1,zhook_handle)
END SUBROUTINE rrtm_cmbgb6