rrtm_taumol10.F90

Go to the documentation of this file.

!*******************************************************************************
SUBROUTINE rrtm_taumol10 (KLEV,P_TAU,&
 & p_tauaerl,p_fac00,p_fac01,p_fac10,p_fac11,k_jp,k_jt,k_jt1,&
 & p_colh2o,k_laytrop,pfrac)  

!     BAND 10:  1390-1480 cm-1 (low - H2O; high - H2O)

! Modifications
!        M.Hamrud      01-Oct-2003 CY28 Cleaning

!     D Salmond   2000-05-15 speed-up
!     JJMorcrette 2000-05-17 speed-up

USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook

USE parrrtm  , ONLY : jplay  ,jpband ,jpgpt  ,ng10   ,ngs9
USE yoerrtwn , ONLY :      nspa   ,nspb
USE yoerrta10, ONLY : absa   ,absb   ,fracrefa, fracrefb

!  Input
!#include "yoeratm.h"

!      REAL TAUAER(JPLAY)

IMPLICIT NONE

!  Output
INTEGER(KIND=JPIM),INTENT(IN)    :: KLEV 
REAL(KIND=JPRB)   ,INTENT(OUT)   :: P_TAU(jpgpt,jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_TAUAERL(jplay,jpband) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC00(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC01(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC10(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC11(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_JP(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_JT(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_JT1(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_COLH2O(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_LAYTROP 
REAL(KIND=JPRB)   ,INTENT(OUT)   :: PFRAC(jpgpt,jplay) 
!- from AER
!- from INTFAC      
!- from INTIND
!- from PROFDATA             
!- from SP             
INTEGER(KIND=JPIM) :: IND0(jplay),IND1(jplay)

INTEGER(KIND=JPIM) :: IG, I_LAY
REAL(KIND=JPRB) :: ZHOOK_HANDLE

!      EQUIVALENCE (TAUAERL(1,10),TAUAER)

!     Compute the optical depth by interpolating in ln(pressure) and 
!     temperature.  

IF (lhook) CALL dr_hook('RRTM_TAUMOL10',0,zhook_handle)
DO i_lay = 1, k_laytrop
  ind0(i_lay) = ((k_jp(i_lay)-1)*5+(k_jt(i_lay)-1))*nspa(10) + 1
  ind1(i_lay) = (k_jp(i_lay)*5+(k_jt1(i_lay)-1))*nspa(10) + 1
ENDDO

!-- DS_000515
DO ig = 1, ng10
  DO i_lay = 1, k_laytrop
!-- DS_000515
    p_tau(ngs9+ig,i_lay) = p_colh2o(i_lay) *&
     & (p_fac00(i_lay) * absa(ind0(i_lay)  ,ig) +&
     & p_fac10(i_lay) * absa(ind0(i_lay)+1,ig) +&
     & p_fac01(i_lay) * absa(ind1(i_lay)  ,ig) +&
     & p_fac11(i_lay) * absa(ind1(i_lay)+1,ig)) &
     & + p_tauaerl(i_lay,10)  
    pfrac(ngs9+ig,i_lay) = fracrefa(ig)
  ENDDO
ENDDO

DO i_lay = k_laytrop+1, klev
  ind0(i_lay) = ((k_jp(i_lay)-13)*5+(k_jt(i_lay)-1))*nspb(10) + 1
  ind1(i_lay) = ((k_jp(i_lay)-12)*5+(k_jt1(i_lay)-1))*nspb(10) + 1
ENDDO

!-- JJM_000517
DO ig = 1, ng10
  DO i_lay = k_laytrop+1, klev
!-- JJM_000517
    p_tau(ngs9+ig,i_lay) = p_colh2o(i_lay) *&
     & (p_fac00(i_lay) * absb(ind0(i_lay)  ,ig) +&
     & p_fac10(i_lay) * absb(ind0(i_lay)+1,ig) +&
     & p_fac01(i_lay) * absb(ind1(i_lay)  ,ig) +&
     & p_fac11(i_lay) * absb(ind1(i_lay)+1,ig)) &
     & + p_tauaerl(i_lay,10)  
    pfrac(ngs9+ig,i_lay) = fracrefb(ig)
  ENDDO
ENDDO

IF (lhook) CALL dr_hook('RRTM_TAUMOL10',1,zhook_handle)
END SUBROUTINE rrtm_taumol10