srtm_cmbgb18.F90

Go to the documentation of this file.

SUBROUTINE srtm_cmbgb18

!     BAND 18:  4000-4650 cm-1 (low - H2O,CH4; high - CH4)
!-----------------------------------------------------------------------

USE parkind1  ,ONLY : jpim , jprb
USE yomhook   ,ONLY : lhook, dr_hook

USE yoesrtwn , ONLY : ngc, ngs, ngn, rwgt
USE yoesrta18, ONLY : ka, kb, selfref, forref, sfluxref, &
                    & kac, kbc, selfrefc, forrefc, sfluxrefc

IMPLICIT NONE

! Local variables
INTEGER(KIND=JPIM) :: JN, JT, JP, IGC, IPR, IPRSM
REAL(KIND=JPRB)    :: ZSUMK, ZSUMF

REAL(KIND=JPRB) :: ZHOOK_HANDLE
!     ------------------------------------------------------------------
IF (lhook) CALL dr_hook('SRTM_CMBGB18',0,zhook_handle)

DO jn = 1,9
  DO jt = 1,5
    DO jp = 1,13
      iprsm = 0
      DO igc = 1,ngc(3)
        zsumk = 0.
        DO ipr = 1, ngn(ngs(2)+igc)
          iprsm = iprsm + 1
          zsumk = zsumk + ka(jn,jt,jp,iprsm)*rwgt(iprsm+32)
        ENDDO
        kac(jn,jt,jp,igc) = zsumk
      ENDDO
    ENDDO
  ENDDO
ENDDO

DO jt = 1,5
  DO jp = 13,59
    iprsm = 0
    DO igc = 1,ngc(3)
      zsumk = 0.
      DO ipr = 1, ngn(ngs(2)+igc)
        iprsm = iprsm + 1
        zsumk = zsumk + kb(jt,jp,iprsm)*rwgt(iprsm+32)
      ENDDO
      kbc(jt,jp,igc) = zsumk
    ENDDO
  ENDDO
ENDDO

DO jt = 1,10
  iprsm = 0
  DO igc = 1,ngc(3)
    zsumk = 0.
    DO ipr = 1, ngn(ngs(2)+igc)
      iprsm = iprsm + 1
      zsumk = zsumk + selfref(jt,iprsm)*rwgt(iprsm+32)
    ENDDO
    selfrefc(jt,igc) = zsumk
  ENDDO
ENDDO

DO jt = 1,3
  iprsm = 0
  DO igc = 1,ngc(3)
    zsumk = 0.
    DO ipr = 1, ngn(ngs(2)+igc)
      iprsm = iprsm + 1
      zsumk = zsumk + forref(jt,iprsm)*rwgt(iprsm+32)
    ENDDO
    forrefc(jt,igc) = zsumk
  ENDDO
ENDDO

DO jp = 1,9
  iprsm = 0
  DO igc = 1,ngc(3)
    zsumf = 0.
    DO ipr = 1, ngn(ngs(2)+igc)
      iprsm = iprsm + 1
      zsumf = zsumf + sfluxref(iprsm,jp)
    ENDDO
    sfluxrefc(igc,jp) = zsumf
  ENDDO
ENDDO

!     -----------------------------------------------------------------
IF (lhook) CALL dr_hook('SRTM_CMBGB18',1,zhook_handle)
END SUBROUTINE srtm_cmbgb18