srtm_cmbgb20.F90

Go to the documentation of this file.

SUBROUTINE srtm_cmbgb20

!     BAND 20:  5150-6150 cm-1 (low - H2O; high - H2O)
!-----------------------------------------------------------------------

USE parkind1  ,ONLY : jpim , jprb
USE yomhook   ,ONLY : lhook, dr_hook

USE yoesrtwn , ONLY : ngc, ngs, ngn, rwgt
USE yoesrta20, ONLY : ka, kb, selfref, forref, absch4, sfluxref, &
                    & kac, kbc, selfrefc, forrefc, absch4c, sfluxrefc

IMPLICIT NONE

! Local variables
INTEGER(KIND=JPIM) :: JT, JP, IGC, IPR, IPRSM
REAL(KIND=JPRB)    :: ZSUMK, ZSUMF1, ZSUMF2

REAL(KIND=JPRB) :: ZHOOK_HANDLE
!     ------------------------------------------------------------------
IF (lhook) CALL dr_hook('SRTM_CMBGB20',0,zhook_handle)

DO jt = 1,5
  DO jp = 1,13
    iprsm = 0
    DO igc = 1,ngc(5)
      zsumk = 0.
      DO ipr = 1, ngn(ngs(4)+igc)
        iprsm = iprsm + 1
        zsumk = zsumk + ka(jt,jp,iprsm)*rwgt(iprsm+64)
      ENDDO
      kac(jt,jp,igc) = zsumk
    ENDDO
  ENDDO

  DO jp = 13,59
    iprsm = 0
    DO igc = 1,ngc(5)
      zsumk = 0.
      DO ipr = 1, ngn(ngs(4)+igc)
        iprsm = iprsm + 1
        zsumk = zsumk + kb(jt,jp,iprsm)*rwgt(iprsm+64)
      ENDDO
      kbc(jt,jp,igc) = zsumk
    ENDDO
  ENDDO
ENDDO

DO jt = 1,10
  iprsm = 0
  DO igc = 1,ngc(5)
    zsumk = 0.
    DO ipr = 1, ngn(ngs(4)+igc)
      iprsm = iprsm + 1
      zsumk = zsumk + selfref(jt,iprsm)*rwgt(iprsm+64)
    ENDDO
    selfrefc(jt,igc) = zsumk
  ENDDO
ENDDO

DO jt = 1,4
  iprsm = 0
  DO igc = 1,ngc(5)
    zsumk = 0.
    DO ipr = 1, ngn(ngs(4)+igc)
      iprsm = iprsm + 1
      zsumk = zsumk + forref(jt,iprsm)*rwgt(iprsm+64)
    ENDDO
    forrefc(jt,igc) = zsumk
  ENDDO
ENDDO

iprsm = 0
DO igc = 1,ngc(5)
  zsumf1 = 0.
  zsumf2 = 0.
  DO ipr = 1, ngn(ngs(4)+igc)
    iprsm = iprsm + 1
    zsumf1 = zsumf1 + sfluxref(iprsm)
    zsumf2 = zsumf2 + absch4(iprsm)*rwgt(iprsm+64)
  ENDDO
  sfluxrefc(igc) = zsumf1
  absch4c(igc) = zsumf2
ENDDO

!     -----------------------------------------------------------------
IF (lhook) CALL dr_hook('SRTM_CMBGB20',1,zhook_handle)
END SUBROUTINE srtm_cmbgb20