srtm_taumol20.F90

Go to the documentation of this file.

SUBROUTINE srtm_taumol20 &
 & ( klev,&
 & p_fac00   , p_fac01  , p_fac10   , p_fac11,&
 & k_jp      , k_jt     , k_jt1     , p_oneminus,&
 & p_colh2o  , p_colch4 , p_colmol,&
 & k_laytrop , p_selffac, p_selffrac, k_indself  , p_forfac, p_forfrac, k_indfor,&
 & p_sfluxzen, p_taug   , p_taur    &
 & )  

!     Written by Eli J. Mlawer, Atmospheric & Environmental Research.

!     BAND 20:  5150-6150 cm-1 (low - H2O; high - H2O)

! Modifications
!        M.Hamrud      01-Oct-2003 CY28 Cleaning

!     JJMorcrette 2003-02-24 adapted to ECMWF environment

!      PARAMETER (MG=16, MXLAY=203, NBANDS=14)

USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook

USE parsrtm  , ONLY : jplay, jpg, ng20
USE yoesrta20, ONLY : absa, absb, forrefc, selfrefc &
 & , sfluxrefc, absch4c, rayl &
 & , layreffr  
USE yoesrtwn , ONLY : nspa, nspb

IMPLICIT NONE

!-- Output
INTEGER(KIND=JPIM),INTENT(IN)    :: KLEV 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC00(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC01(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC10(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FAC11(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_JP(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_JT(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_JT1(jplay) 
REAL(KIND=JPRB)                  :: P_ONEMINUS ! Argument NOT used
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_COLH2O(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_COLCH4(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_COLMOL(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_LAYTROP 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_SELFFAC(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_SELFFRAC(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_INDSELF(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FORFAC(jplay) 
REAL(KIND=JPRB)   ,INTENT(IN)    :: P_FORFRAC(jplay) 
INTEGER(KIND=JPIM),INTENT(IN)    :: K_INDFOR(jplay) 

REAL(KIND=JPRB)   ,INTENT(OUT)   :: P_SFLUXZEN(jpg) 
REAL(KIND=JPRB)   ,INTENT(OUT)   :: P_TAUG(jplay,jpg) 
REAL(KIND=JPRB)   ,INTENT(OUT)   :: P_TAUR(jplay,jpg) 
!- from INTFAC      
!- from INTIND
!- from PRECISE             
!- from PROFDATA             
!- from SELF             
INTEGER(KIND=JPIM) :: IG, IND0, IND1, INDS, INDF, I_LAY, I_LAYSOLFR, I_NLAYERS

REAL(KIND=JPRB) ::  &
 & Z_TAURAY  
REAL(KIND=JPRB) :: ZHOOK_HANDLE

IF (lhook) CALL dr_hook('SRTM_TAUMOL20',0,zhook_handle)
i_nlayers = klev

!     Compute the optical depth by interpolating in ln(pressure), 
!     temperature, and appropriate species.  Below LAYTROP, the water
!     vapor self-continuum is interpolated (in temperature) separately.  

i_laysolfr = k_laytrop

DO i_lay = 1, k_laytrop
  IF (k_jp(i_lay) < layreffr .AND. k_jp(i_lay+1) >= layreffr) &
   & i_laysolfr = min(i_lay+1,k_laytrop)  
  ind0 = ((k_jp(i_lay)-1)*5+(k_jt(i_lay)-1))*nspa(20) + 1
  ind1 = (k_jp(i_lay)*5+(k_jt1(i_lay)-1))*nspa(20) + 1
  inds = k_indself(i_lay)
  indf = k_indfor(i_lay)
  z_tauray = p_colmol(i_lay) * rayl

!  DO IG = 1, NG(20)
  DO ig = 1 , ng20
    p_taug(i_lay,ig) = p_colh2o(i_lay) * &
     & ((p_fac00(i_lay) * absa(ind0,ig) + &
     & p_fac10(i_lay) * absa(ind0+1,ig) + &
     & p_fac01(i_lay) * absa(ind1,ig) + &
     & p_fac11(i_lay) * absa(ind1+1,ig)) + &
     & p_selffac(i_lay) * (selfrefc(inds,ig) +  &
     & p_selffrac(i_lay) * &
     & (selfrefc(inds+1,ig) - selfrefc(inds,ig))) + &
     & p_forfac(i_lay) * (forrefc(indf,ig) + &
     & p_forfrac(i_lay) * &
     & (forrefc(indf+1,ig) - forrefc(indf,ig)))) &
     & + p_colch4(i_lay) * absch4c(ig)  
!     &           + TAURAY &
!    SSA(LAY,IG) = TAURAY/TAUG(LAY,IG)
    p_taur(i_lay,ig) = z_tauray 
    IF (i_lay == i_laysolfr) p_sfluxzen(ig) = sfluxrefc(ig) 
  ENDDO
ENDDO

DO i_lay = k_laytrop+1, i_nlayers
  ind0 = ((k_jp(i_lay)-13)*5+(k_jt(i_lay)-1))*nspb(20) + 1
  ind1 = ((k_jp(i_lay)-12)*5+(k_jt1(i_lay)-1))*nspb(20) + 1
  indf = k_indfor(i_lay)
  z_tauray = p_colmol(i_lay) * rayl

!  DO IG = 1, NG(20)
  DO ig = 1 , ng20
    p_taug(i_lay,ig) = p_colh2o(i_lay) * &
     & (p_fac00(i_lay) * absb(ind0,ig) + &
     & p_fac10(i_lay) * absb(ind0+1,ig) + &
     & p_fac01(i_lay) * absb(ind1,ig) + &
     & p_fac11(i_lay) * absb(ind1+1,ig) + &
     & p_forfac(i_lay) * (forrefc(indf,ig) + &
     & p_forfrac(i_lay) * &
     & (forrefc(indf+1,ig) - forrefc(indf,ig)))) + &
     & p_colch4(i_lay) * absch4c(ig)  
!     &           TAURAY + &
!    SSA(LAY,IG) = TAURAY/TAUG(LAY,IG)
    p_taur(i_lay,ig) = z_tauray 
  ENDDO
ENDDO

!-----------------------------------------------------------------------
IF (lhook) CALL dr_hook('SRTM_TAUMOL20',1,zhook_handle)
END SUBROUTINE srtm_taumol20