surhcri.F90

Go to the documentation of this file.

!-----------------------------------------------------------------------
      SUBROUTINE surhcri(KULOUT)
!-----------------------------------------------------------------------
!
!**** *SURHCRI * - COMPUTATION OF THE CRTITICAL RELATIVE HUMIDITY
!                  PROFILE FOR SMITH'S CONDENSATION SCHEME.
!
!**   Interface.
!     ----------
!        *CALL* *SURHCRI*
!
!-----------------------------------------------------------------------
!
! -   ARGUMENTS D'ENTREE./INPUT ARGUMENTS.
!     ------------------------------------
!
!-----------------------------------------------------------------------
!
! -   ARGUMENTS IMPLICITES.
!     ---------------------
!
! COMMON /YOMPHY/
! COMMON /YOMPHY0/
!
!*
!-----------------------------------------------------------------------
!
!     Auteur.
!     -------
!         05-03, Luc Gerard (from Ph. Lopez acrhcri)
!
!     Modifications.
!     --------------
!         06-10, nettoyage - R. Brozkova
!-----------------------------------------------------------------------
!
USE parkind1  ,ONLY : jpim     ,jprb
USE yomhook   ,ONLY : lhook,   dr_hook
!
USE yomphy0   , ONLY : rhcrit1, rhcrit2, retamin, grhcmod, rhcri ,nrhcri 
USE yomdim    , ONLY : nflevg
USE yomgc     , ONLY : gaw, gm
USE yomgem    , ONLY : vp00, teqh
USE yomphy    , ONLY : lgwrhcri
USE yomsta    , ONLY : stpre 
 
IMPLICIT NONE
 
INTEGER (KIND=JPIM),INTENT(IN) :: KULOUT
 
! LOCAL
 
REAL(KIND=JPRB) :: ZVETAF
REAL(KIND=JPRB) :: ZGAW0,ZEGAW,ZFACT,ZFACT0,ZFACTA,ZFACTB,ZFACTC, &
        & ZA,ZB,ZC
INTEGER (KIND=JPIM) :: JLEV
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('SURHCRI',0,zhook_handle)
 
!     ------------------------------------------------------------------
 
IF(nrhcri == nflevg) THEN
 
!     ------------------------------------------------------------------
 
! CRITICAL RELATIVE HUMIDITY PROFILE
! DEPENDENT ON THE LOCAL RESOLUTION.
! ----------------------------------
 
   zfact0=(retamin*(retamin-1._jprb))**2
   zfacta=(2._jprb*retamin-1._jprb)
   zfactb=(1._jprb-3._jprb*retamin**2)
   zfactc=(3._jprb*retamin-2._jprb)*retamin
   IF (lgwrhcri) THEN
     zgaw0=2.42e-05_jprb
     zegaw=(1.0_jprb-exp(-gaw(1)/zgaw0))/zfact0
   ELSE
     zegaw=(1.0_jprb-grhcmod*exp(-1.0_jprb/(teqh*gm(1))))/zfact0
   ENDIF
 
   zfact=(rhcrit2-rhcrit1)*zegaw
   za=zfacta*zfact
   zb=zfactb*zfact
   zc=zfactc*zfact
 
   DO jlev=1,nflevg
     zvetaf=stpre(jlev)/vp00
     rhcri(jlev) = za * zvetaf**3 &
                     & + zb * zvetaf**2 &
                     & + zc * zvetaf &
                     & + rhcrit2
   ENDDO   
 
   WRITE(kulout,'(A)') 'RHCRI: SMITH SCHEME CRITICAL RH PROFILE:'
   WRITE(kulout,'((10(G9.3)))') (rhcri(jlev),jlev=1,nflevg)
ELSE
   WRITE(kulout,*) 'NRHCRI=',nrhcri,': GLOBAL MODEL, NO RHCRI INITIALISATION IN SETUP'
ENDIF
IF (lhook) CALL dr_hook('SURHCRI',1,zhook_handle)
END SUBROUTINE surhcri